Wednesday, December 14, 2011

More on Pango Markup Strings

I don't like fiddling around with markup strings, even at the best of times. So, any convienient way of producing the right formatting is welcome news to me. Gtk widgets allow markupstrings for various text elements. So, I thought, how about creating strings on the fly using familiar Tcl means. Hence the following two procs below. One will create markup and the other remove it. The removal method is still basic, it will also strip out markup-like items such as <b> so its use is limited. It is also assumed that there will only be one "<span"  entry per string. Modifying the code to remove more that one <span group should not be too much of an issue.

The need behind creating these procs comes from wanting to quickly add/remove markup strings from tree/listview cells.

#---------------
# pango_string.tcl
#---------------
# !/bin/sh
# the next line restarts using tclsh \
exec tclsh "$0" "$@"
package require Gnocl

#---------------
# Create Pango formatted string.
#---------------
# Arguments
#    str        The text string to format.
#    args    Matched pair of options and values.
# Returns
#---------------
proc pango_string {str args} {
    set span_str ""
    foreach {a b} $args {
        puts "a = $a b = $b"
        switch -- $a {
            -big {
                if {$b} {set str  "<big>$str</big>" }
                }
            -bold {
                if {$b} { set str  "<b>$str</b>" }
                }
            -italic {
                if {$b} { set str  "<i>$str</i>" }
                }
            -small {
                if {$b} { set str  "<small>$str</small>" }
                }
            -strikethrough {
                if {$b} { set str  "<s>$str</s>" }
                }
            -sub {
                if {$b} { set str  "<sub>$str</sub>" }
                }
            -sup {
                if {$b} { set str  "<sup>$str</sup>"}
                }
            -tt {
                if {$b} { set str  "<tt>$str</tt>" }
                }
            -bg -
            -bgClr -
            -background {
                append span_str " background=\"$b\""
                }
            -fallback {
                append span_str " fallback=\"$b\""
                }
            -font {
                append span_str " font=\"$b\""
                }
            -fg -
            -fgClr -
            -foreground {
                append span_str " foreground=\"$b\""
                }
            -gravity {
                append span_str " gravity=\"$b\""
                }
            -gravityHint {
                append span_str " gravity_hint=\"$b\""
                }               
            -lang {
                append span_str " lang=\"$b\""
                }
            -rise {
                append span_str " rise=\"$b\""
                }
            -style {
                append span_str " style=\"$b\""
                }   
            -size {
                append span_str " size=\"$b\""
                }
            -letterSpacing {
                append span_str " letter_spacing=\"$b\""
                }
            -stretch {
                append span_str " stretch=\"$b\""
                }
            -strikethroughColor {
                append span_str " strikethrough_color=\"$b\""
                }
            -underline {
                if {$b == 1} {
                    set str  "<u>$str</u>"
                    } else {
                    append span_str " underline=\"$b\""
                    }
                }
            -underlineColor {
                append span_str " underline_color=\"$b\""
                }
            -variant {
                append span_str " size=\"$b\""
                }
            -weight {
                append span_str " size=\"$b\""
                }

        }
    }
   
    if {$span_str != ""} {
        set str "<span $span_str>$str</span>"
    }
   
    return $str
}


if {1} {
    set box [gnocl::box -orientation vertical]

    for {set i 0} {$i <= 5} {incr i} {
        set lab($i) [gnocl::label]
        $box add $lab($i)
    }

    $lab(0) configure -text [pango_string "Hello World" -bold 1]
    $lab(1) configure -text [pango_string "Hello World" -bold 1 -foreground red]
    $lab(2) configure -text "[pango_string "Hello" -bold 1 -foreground red] [pango_string "World" -bold 1 -foreground blue -italic 1]"
    $lab(3) configure -text "[pango_string "Hello" -stretch ultraexpanded -bold 1 -foreground red] [pango_string "World" -bold 1 -foreground blue -italic 1]"
    gnocl::window -child $box
}

#---------------
# Remove pango formatting from a string.
#---------------
# Arguments
#    str        string with pango markup
# Returns
#    plain text string
# Notes
#   Use with caution.
#    Will also strip <u> etc., from within text strings.
#---------------
proc pango_remove {str} {
    set str [string map {
        <u>     "" </u>     ""
        <b>     "" </b>     ""
        <i>     "" </i>     ""
        <s>     "" </s>     ""
        <big>   "" </big>   ""
        <small> "" </small> ""
        <sub>   "" </sub>   ""
        <sup>   "" </sup>   ""
        <tt>    "" </tt>    ""
        </span> ""
    } $str]

    # remove span
    set i [string first "<span" $str]
    if {!$i} {
        set j [string first ">" $str]
        set str [string range $str [incr j] end]
    }


    return $str
}

if {1} {
    set markup(block) "-fg red -bold 1"
    set str [eval pango_string "NO-<b>PANGO" $markup(block) ]
    puts $str
    puts ==|[pango_remove $str]|==
}


No comments: